1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
SUMMARY = "The tdb library"
SECTION = "libs"
LICENSE = "LGPL-3.0+ & GPL-3.0+"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/LGPL-3.0;md5=bfccfe952269fff2b407dd11f2f3083b \
file://${COREBASE}/meta/files/common-licenses/GPL-3.0;md5=c79ff39f19dfec6d293b95dea7b07891"
SRC_URI = "http://samba.org/ftp/tdb/tdb-${PV}.tar.gz \
file://do-not-check-xsltproc-manpages.patch \
file://tdb-Add-configure-options-for-packages.patch \
"
SRC_URI[md5sum] = "c98f24eb469022b0f1741d3a504cfda5"
SRC_URI[sha256sum] = "5578fb726bd04835f250bea11fe7d1398fe0bb3a7c9390404241c83cd6b50c1c"
PACKAGECONFIG ??= "\
${@bb.utils.contains('DISTRO_FEATURES', 'acl', 'acl', '', d)} \
${@bb.utils.contains('DISTRO_FEATURES', 'xattr', 'attr', '', d)} \
"
PACKAGECONFIG[acl] = "--with-acl,,acl"
PACKAGECONFIG[attr] = "--with-attr,,attr"
PACKAGECONFIG[libaio] = "--with-libaio,,libaio,"
PACKAGECONFIG[libcap] = "--with-libcap,,libcap,"
PACKAGECONFIG[valgrind] = "--with-valgrind,,valgrind,"
S = "${WORKDIR}/tdb-${PV}"
inherit waf-samba
EXTRA_OECONF += "--disable-rpath \
--bundled-libraries=NONE \
--builtin-libraries=replace \
--with-libiconv=${STAGING_DIR_HOST}${prefix}\
"
DISABLE_STATIC = ""
PACKAGES += "tdb-tools python-tdb python-tdb-dbg"
FILES_${PN} = "${libdir}/*.so.*"
FILES_tdb-tools = "${bindir}/*"
FILES_python-tdb = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/*"
FILES_python-tdb-dbg = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/.debug/*"
RDEPENDS_python-tdb = "python"
|