blob: 37803618695f8356329b60591b3a78dd12574a67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
#
# Copyright OpenEmbedded Contributors
#
# SPDX-License-Identifier: MIT
#
inherit setuptools3-base python_pep517
DEPENDS += "python3-setuptools-native python3-wheel-native"
SETUPTOOLS_BUILD_ARGS ?= ""
SETUPTOOLS_SETUP_PATH ?= "${S}"
do_check_backend() {
BACKEND=$(grep -s 'build-backend.*=' ${SETUPTOOLS_SETUP_PATH}/pyproject.toml) || true
if test -n "$BACKEND"; then
bbwarn inherits setuptools3 but has pyproject.toml with $BACKEND
fi
}
addtask check_backend after patch before configure
setuptools3_do_configure() {
:
}
setuptools3_do_compile() {
cd ${SETUPTOOLS_SETUP_PATH}
NO_FETCH_BUILD=1 \
STAGING_INCDIR=${STAGING_INCDIR} \
STAGING_LIBDIR=${STAGING_LIBDIR} \
${STAGING_BINDIR_NATIVE}/python3-native/python3 setup.py \
bdist_wheel --verbose --dist-dir ${PEP517_WHEEL_PATH} ${SETUPTOOLS_BUILD_ARGS} || \
bbfatal_log "'python3 setup.py bdist_wheel ${SETUPTOOLS_BUILD_ARGS}' execution failed."
}
setuptools3_do_compile[vardepsexclude] = "MACHINE"
do_compile[cleandirs] += "${PEP517_WHEEL_PATH}"
# This could be removed in the future but some recipes in meta-oe still use it
setuptools3_do_install() {
python_pep517_do_install
}
EXPORT_FUNCTIONS do_configure do_compile do_install
export LDSHARED="${CCLD} -shared"
|
